Computing Pi

Archimedes ( $\sim$ 250 BC)

Estimates $π$ using the perimeters of regular polygons inscribed in and circumscribed about a circle of diameter 1. In the function below, each iteration doubles the number of polygon sides.

function polygon(n)
    # start with a hexagon
    a = 2 √3
    b = 3
    for i in 1:n
      a = (2 a b) / (a + b)
      b = √(a b)
    end
    return (a + b) / 2
end

$polygon (4) = 3.14187327526794$ , good to 4 significant digits for a 96-sided polygon

Viete (1597)

$\frac{2}{π} = \frac{\sqrt{2}}{2} \cdot \frac{\sqrt{2 + \sqrt{2}}}{2} \cdot \frac{\sqrt{2 + \sqrt{2 + \sqrt{2}}}}{2} \dots$

function viete(numTerms)
   product = 1
   radicand = 0
   for i in 1:numTerms
      radicand = √(2.0 + radicand)
      product = product × (radicand / 2)
   end
   return 2 / product
end

$viete (10) = 3.1415914215112$ , good to 6 significant digits after 10 terms.

Leibnitz (1673)

$\frac{π}{4} = 1 - \frac{1}{3} + \frac{1}{5} - \frac{1}{7} + \dots = 4 \sum_{n = 0}^{\infty} \frac{(- 1)^{n}}{1 + 2 n}$

$π_{approx} = 4 \sum_{n = 0}^{24} \frac{(- 1)^{n}}{1 + 2 n} = 3.18157668543503$

Well, that converges slowly. Only 2 significant digits after 25 terms.

Ramanujan (1914)

$\frac{1}{π} = \frac{2 \sqrt{2}}{9, 801} \sum_{n = 0}^{\infty} \frac{(4 n)! (1, 103 + 26, 390 n)}{(n!)^{4} 39 6^{4 n}}$

$f o r m a t = f30$

First, let’s calculate $\sqrt{2}$ to high precision: $s q r t T w o = sqRt (2, 1 e- 50) = 1.414213562373095048801688724210$

$π_{approx} = \frac{9, 801}{2 \cdot s q r t T w o \times \sum_{n = 0}^{2} \frac{(4 n)! (1, 103 + 26, 390 n)}{(n!)^{4} 39 6^{4 n}}} = 3.141592653589793238462649065703$

That’s 24 significant digits from 3 terms. Impressive.

Chudonovsky (1987)

$\frac{1}{π} = 12 \sum_{n = 0}^{\infty} \frac{(- 1)^{n} (6 n)! (13, 591, 409 + 545, 140, 134 n)}{(3 n)! (n!)^{3} (640, 32 0^{3})^{n + 1 ∕ 2}}$

$s q r t B i g N u m = sqRt (640, 32 0^{3}, 1 e- 100) = 512, 384, 047.996000749812554669927915299280$

$f o r m a t = f43$

$π_{approx} = \frac{1}{12 \sum_{n = 0}^{2} \frac{(- 1)^{n} (6 n)! (13, 591, 409 + 545, 140, 134 n)}{(3 n)! (n!)^{3} (640, 32 0^{3})^{n} \cdot s q r t B i g N u m}} = 3.1415926535897932384626433832795028841971677$

42 significant digits from the first 3 terms. Each term adds at least 14 digits.

Two of these methods needed high-precision square roots. We got them from a function for Square Roots via Newton’s Method.

function sqRt(a; ε = 1e-15)
    x = √a  # ~15 significant digits
    while true
        if |x² - a| ≤ ε return x
        x = (x + a / x) / 2
    end
end